sekaita.com

; $Header: $

stacksize 4096

segment .data            
    newlineStr      db      "\n", 0
    spaceStr        db      " ", 0
    colonStr        db      ":", 0

    nickStr         db      "NICK sekaitaBot\r\n", 0
    userStr         db      "USER sekaitaBot 8 * :virtual machine ircbot\r\n", 0
    pingStr         db      "PING :", 0
    pongStr         db      "PONG :", 0
    joinStr         db      "JOIN #stoner.uk\r\n", 0
    partStr         db      "PART #stoner.uk\r\n", 0
    messageStr      db      "PRIVMSG", 0
    noticeStr       db      "NOTICE", 0

    errorStr        db      "!! Error occurred\n", 0
    exceptionStr    db      "!! Unhandled exception occurred\n", 0

    connectingMsg0  db      "!! Connecting to '", 0
    connectingMsg1  db      "' on port '", 0
    connectingMsg2  db      "'...", 0

    connectErrMsg   db      "!! Unable to initialise connection...\n", 0
    errorCodeMsg    db      "!! Error code: ", 0

    disconnectMsg   db      "!! Disconnecting from server...\n", 0

    connClosedMsg   db      "!! Connection has been closed...\n", 0
    connLostMsg     db      "!! Connection lost...\n", 0

    inputPrefix     db      "<< ", 0
    outputPrefix    db      ">> ", 0

    dbg1    db      "## appending buffers\n", 0
    dbg2    db      "## resizing buffer\n", 0

    readLineLoopStr db  "readline loop\n", 0
    mainLoopStr     db  "main loop\n", 0

    rlStr0  db  "readline write offset: ", 0
    rlStr1  db  "readline received data: ", 0

    sdStr0  db  "sending data: ", 0
    sdStr1  db  "data length: ", 0

    plStr0  db  "is ping request\n", 0
    plStr1  db  "isnt ping request\n", 0

segment .text
    import  net.connect
    import  net.disconnect
    import  net.send
    import  net.recv
    import  net.canSend
    import  net.canRecv
    import  net.getLastError
   
    import  std.memset
    import  std.memcpy
    import  std.memcmp
    import  std.memchr

    import  std.strlen
    import  std.strncpy
    import  std.strstr
    import  std.indexof
    import  std.substr

    import  std.cout

    import  strlib.StrToInt
    import  strlib.IntToStr

    shared  printStr
    shared  printInt

    export  main

; -------------------------------------
; void main(char* address = "irc.quakenet.org:6667")

main:
    nvar    0,  argStr
    nvar    1,  arg1Str
    nvar    2,  arg2Str
    nvar    3,  parseRes
    nvar    4,  connectResult
    // eter frame and setup variables
    entf    5,  1
    movi    arg1Str,    0
    movi    arg2Str,    0
    // set exception handler
    sexh    .exception
    // parse argument string into parts
    push    argStr
    pshd    colonStr
    padr    arg1Str
    padr    arg2Str
    call    parseArgs
    popr    parseRes,   4
    // if the return value is zero, an error occurred
    jz      parseRes,   .error
    // if either are null, an error occurred
    jz      arg1Str,    .error
    jz      arg2Str,    .error
    // print out what we are connecting to
    push    arg1Str
    push    arg2Str
    call    printConnectingMsg
    popn    2
    // initialise the connection
    push    arg1Str
    push    arg2Str
    call    initialiseConnection
    popr    connectResult,  2

    jz      connectResult,  .error
    // enter the main loop
    push    connectResult
    call    mainLoop2
    //
    lrtn

.exception:
    // exception handler
    pshd    exceptionStr
    farc    std.cout
    popn    1

    jmp .finally

.error:
    // exception handler
    pshd    errorStr
    farc    std.cout
    popn    1

    jmp .finally

.finally:
    del     arg1Str
    del     arg2Str

    lrtn



; -------------------------------------
initialiseConnection:
    // parameters
    nvar    0,  addressStr
    nvar    1,  portNumStr
    // local variables
    nvar    2,  portNumInt
    nvar    3,  connID
    nvar    4,  sendResult
    nvar    5,  errorCode
    //
    entf    5,  2
    //
    sexh    .errorOccurred
    // convert the port number into an integer
    push    portNumStr     
    farc    strlib.StrToInt
    popr    portNumInt, 1          
    // connect to the specified server
    push    addressStr
    push    portNumInt
    farc    net.connect
    popr    connID, 2
    // exit if a connection wasnt made
    jlz     connID, .errorOccurred
    // send nick information to server
    push    connID
    call    sendNick
    popr    sendResult, 1
    //
    jlz     sendResult, .errorOccurred
    // send user information to server
    push    connID
    call    sendUser
    popr    sendResult, 1
    //
    jlz     sendResult, .errorOccurred
    // try to join a channel
    //push  connID
    //call  joinChannel
    //popr  sendResult, 1
    ////
    //jlz       sendResult, .errorOccurred
    //
    lret    connID

.errorOccurred:

    pshd    connectErrMsg
    call    printStr
    popn    1

    farc    net.getLastError
    pop     errorCode

    pshd    errorCodeMsg
    call    printStr
    popn    1

    push    errorCode
    pshi    16
    farc    strlib.IntToStr
    farc    std.cout
    popn    3

    pshd    newlineStr
    call    printStr
    popn    1

    push    connID
    call    disconnect

    lrti    0

; -------------------------------------
sendNick:
    nvar    0,  connID
    nvar    1,  nickStrLen
    nvar    2,  sendResult
    nvar    3,  canSend

    entf    4,  1

    pshd    nickStr
    farc    std.strlen
    popr    nickStrLen, 1

.cantSend:
    // see if data can be sent
    push    connID
    farc    net.canSend
    popr    canSend,    1
    //
    // loop until the data can be sent
    jz      canSend,    .cantSend
    // if an error occurred, give up
    jlz     canSend,    .errorOccurred

    push    connID
    pshd    nickStr
    push    nickStrLen
    call    sendData
    popr    sendResult, 3
    // return the number of bytes sent
    lret    sendResult

.errorOccurred:
    lrti    -1


   


; -------------------------------------
sendUser:
    nvar    0,  connID
    nvar    1,  sendResult
    nvar    2,  userStrLen

    entf    3,  1

    pshd    userStr
    farc    std.strlen
    popr    userStrLen, 1

    push    connID
    pshd    userStr
    push    userStrLen
    call    sendData
    popr    sendResult, 2
    // return the number of bytes sent
    lret    sendResult

    //push  connID
    //farc  net.canSend
    //popr  canSend,    1


; -------------------------------------
joinChannel:
    nvar    0,  connID
    nvar    1,  sendResult
    nvar    2,  joinStrLen

    entf    3,  1

    pshd    userStr
    farc    std.strlen
    popr    joinStrLen, 1

    push    connID
    pshd    joinStr
    push    joinStrLen
    call    sendData
    popr    sendResult, 2
    // return the number of bytes sent
    lret    sendResult

; -------------------------------------
mainLoop2:
    nvar    0,  connID
    nvar    1,  recvResult
    nvar    2,  sendResult
    nvar    3,  readLineResult
    nvar    4,  errorCode
    // return codes
    nvar    5,  codeConnLost
    nvar    6,  codeConnError

    nvar    7,  dataBuffer
    nvar    8,  dataBufferSize
    nvar    9,  newlineOffs

    nvar    10, lineStr
    nvar    11, lineLength

    entf    12, 1

    movi    codeConnLost,   -2
    movi    codeConnError,  -1

    movi    dataBufferSize, 0
    movi    dataBuffer,     0

.loop:
//  pshd    mainLoopStr
//  call    printStr
//  popn    1

    // try to read stuff from the connection
    push    connID
    padr    dataBuffer
    push    dataBufferSize
    call    readLine
    popr    readLineResult, 3
    // connection was closed (-2)
    jcmp    readLineResult, codeConnLost,   .connectionClosed
    // error on connection (-1)
    jlz     readLineResult, .errorEncountered
    // else a line of text was read from the data stream

    mov     dataBufferSize, readLineResult


    // while data contains a newline

    //push  dataBuffer
    //push  dataBufferSize
    //call  containsNewline
    //popr  newlineOffs,    3

    push    connID
    padr    dataBuffer
    push    dataBufferSize
    call    processData
    popr    dataBufferSize, 3



    //mov       newlineOffs,    readLineResult
    //// get the length of the first line in the buffer
    //mov       lineLength,     newlineOffs
    //sub       lineLength,     dataBuffer
    //inc       lineLength
    //// extract the line from the buffer
    //push  lineStr
    //push  dataBuffer
    //pshi  0
    //push  lineLength
    //farc  std.substr
    //popn  4



    // check the data buffer to see if its a ping request


.noDataReceived:
    jmp     .loop

.connectionClosed:

    pshd    connClosedMsg
    farc    std.cout
    popn    1

.loopEnd:
    del     dataBuffer
    lrtn

.errorEncountered:

    pshd    connLostMsg
    farc    std.cout
    popn    1

    jmp     .loopEnd

; -------------------------------------
; // reads data from the connection until
; // a newline '\n' is sent - returns the
; // character index of the first newline
; int readLine(uint connID, char** buff, uint size)

readLine:
    // parameters
    nvar    0,  connID
    nvar    1,  dataBufferPtr
    nvar    2,  dataBufferSize
    // local variables
    nvar    3,  recvBuffer
    nvar    4,  recvBufferSize
    nvar    5,  recvDataSize

    nvar    6,  dataBufferOffs
    nvar    7,  containsNewln

    nvar    8,  codeConnLost
    nvar    9,  codeConnError
    nvar    10, dataBuffer

    entf    11, 3
    // setup a temporary buffer to store received data
    movi    recvBufferSize, 1024
    new     recvBuffer, recvBufferSize
    // start writing into the data buffer at its beginning
    movi    dataBufferOffs, 0
    // setup error codes
    movi    codeConnLost,   -2
    movi    codeConnError,  -1
   
.loop:

//  pshd    readLineLoopStr
//  call    printStr
//  popn    1

    // try to read data from the connection
    push    connID
    push    recvBuffer
    push    recvBufferSize
    call    recvData
    popr    recvDataSize,   3
    // if there is no data to receive
    jz      recvDataSize,   .loop
    // or the connection was closed (-2)
    jcmp    recvDataSize,   codeConnLost,   .connectionClosed
    // or there was an error on the connection (-1)
    jcmp    recvDataSize,   codeConnError,  .errorEncountered

    // else data was received

    // copy received data into passed in buffer
    push    dataBufferPtr
    push    dataBufferSize
    push    recvBuffer
    push    recvDataSize
    push    dataBufferOffs
    call    appendBuffers
    popr    dataBufferSize, 5
    // increment the write offset to account for appended data
    add     dataBufferOffs,     recvDataSize

    //pshd  rlStr0
    //call  printStr
    //push  dataBufferOffs
    //call  printInt
    //pshd  rlStr1
    //call  printStr
    //push  recvBuffer
    //call  printStr
    //popn  4

// NOTICE AUTH :*** Looking up your hostname

    jz      dataBufferPtr,  .nullDataBuffer
    // dereference the pointer
    load    dataBuffer,     dataBufferPtr

    // store the new buffer pointer
//  stor    dataBufferPtr,  dataBuffer
    // search the buffer for a newline
    push    dataBuffer
    push    dataBufferSize
    call    containsNewline
    popr    containsNewln,  2
    // if the buffer does not contain a newline char, loop
    jz      containsNewln,  .loop
    // return the size of the buffer (only if the buffer contains a newline)
    lret    dataBufferSize

.nullDataBuffer:
    jmp     .loop

.connectionClosed:

    lrti    -2

.errorEncountered:

    pshd    connLostMsg
    farc    std.cout
    popn    1

    lrti    -1

; -------------------------------------
; //
; void processData(byte** buff, uint size)

processData:
    nvar    0,  connID
    nvar    1,  buffPtr
    nvar    2,  size
    //
    nvar    3,  buff
    nvar    4,  nlOffset
    nvar    5,  lineBuff
    nvar    6,  lineBuffSize
    //
    entf    7,  3
    //
.loop:

    load    buff,   buffPtr
    // does the data contain a newline?
    push    buff
    push    size
    call    containsNewline
    popr    nlOffset,   2
    // if the buffer contains a newline char
    jnz     nlOffset,   .newlineFound
    // else return
    jmp     .finished
.newlineFound:
    // get the offset relative to buff
    sub     nlOffset,   buff
    inc     nlOffset
    // set the temp buffer to be +1 in size (for \0)
    mov     lineBuffSize,   nlOffset
    inc     lineBuffSize
    new     lineBuff,   lineBuffSize
    // copy out the newline
    push    lineBuff
    push    buff
    pshi    0
    push    nlOffset
    farc    std.substr
    popn    4
    // remove the copied out data from the buffer
    push    buffPtr
    push    size
    push    nlOffset
    call    lefttrimBuffer
    popr    size,   3
    // process the line
    push    connID
    push    lineBuff
    push    lineBuffSize
    call    processLine
    popn    3
    // loop until nothing is left
    jmp     .loop

.finished:
    // return the size of the resized buffer
    lret    size

; -------------------------------------
processLine:
    // parameters
    nvar    0,  connID
    nvar    1,  buff
    nvar    2,  size
    // local variables
    nvar    3,  isPing
    nvar    4,  retVal
    //
    entf    5,  3
    // print out the received line of data
    push    buff
    call    printInput
    popn    1

.pingTest:
    // determine if the line is a ping request
    push    buff
    push    size
    call    isPingReq
    popr    isPing,     1
    // if it is a ping request
    jnz     isPing,     .isPing
    // else continue
.isntPing:
    //pshd  plStr1
    //call  printStr
    //popn  1

    jmp     .finished

.isPing:
    //
    //pshd  plStr0
    //call  printStr
    //popn  1

    // construct a pong response
    push    connID
    push    buff
    push    size
    call    sendPong
    popr    retVal, 3

.finished:

    lrtn

; -------------------------------------
isPingReq:
    // parameters
    nvar    0,  buff
    nvar    1,  size
    // local variables
    nvar    3,  pingBuff
    nvar    4,  pingBuffSz
    nvar    5,  isPing

    entf    6,  2

    // get the first 6 characters of the buffer (7 for \0)
    movi    pingBuffSz, 7
    new     pingBuff,   pingBuffSz
    dec     pingBuffSz

    push    pingBuff
    push    buff
    push    pingBuffSz
    farc    std.memcpy

    // if they are equal to 'PING :'
    push    pingBuff
    pshd    pingStr
    push    pingBuffSz
    farc    std.memcmp
    popr    isPing, 3

    del     pingBuff

    jz      isPing,     .isPing

    lrti    0

.isPing:
   

    lrti    1

; -------------------------------------
sendPong:
    // parameters
    nvar    0,  connID
    nvar    1,  buff
    nvar    2,  size
    // local variables
    nvar    3,  pongData
    nvar    4,  pongDataSz
    nvar    5,  prefixLen
    nvar    6,  retVal
    nvar    7,  resp
    nvar    8,  respLen
    nvar    9,  dataOffs
    //
    entf    10, 3
    // create a buffer to hold the response
    mov     respLen,    size
    new     resp,       respLen
    // get the length of the pong prefix
    pshd    pongStr
    farc    std.strlen
    popr    prefixLen,  1
    // copy the pongStr string into the response buffer
    push    resp
    pshd    pongStr
    push    prefixLen
    farc    std.memcpy
    popn    3
    // get the pointer to where to start writing th pong data
    mov     dataOffs,   resp
    add     dataOffs,   prefixLen
    // get the size of the unique ping data
    mov     pongDataSz, size
    sub     pongDataSz, prefixLen
    // copy the data into the buffer
    padr    dataOffs
    push    pongDataSz
    push    buff
    push    prefixLen
    push    pongDataSz
    call    subBuffer
    popr    retVal, 5
    //
    jz      retVal, .errorOccurred
    //
    push    connID
    push    resp
    push    size
    call    sendData
    popr    retVal, 3
    //
    del     resp
    //
    jz      retVal, .errorOccurred


    push    connID
    call    joinChannel
    popn    1

    lrti    1

.errorOccurred:
    lrti    0



; -------------------------------------
containsNewline:
    nvar    0,  buff
    nvar    1,  size
    //
    nvar    2,  nlOffset
    //
    entf    3,  2
    // check if the data contain a newline
    push    buff
    pshi    10                  ; newline character value (0x0A)
    push    size
    farc    std.memchr
    popr    nlOffset,   3
    lret    nlOffset


; -------------------------------------
disconnect:
    nvar    0,  connID
    entf    1,  1

    pshd    disconnectMsg
    call    printStr
    popn    1

    farc    net.disconnect
    lrtn

; -------------------------------------
; char* parseArgs(char* src, char* separator, char** arg1, char** arg2)

parseArgs:
    // parameters
    nvar    0,  srcStr
    nvar    1,  separatorStr
    nvar    2,  arg1ptr
    nvar    3,  arg2ptr
    // local variables
    nvar    4,  srcLength
    nvar    5,  sepOffset
    nvar    6,  arg1str
    nvar    7,  arg1len
    nvar    8,  arg2str
    nvar    9,  arg2len
    // enter a new stack frame
    entf    10,     4
    // set exception handler
    sexh    .exceptionHandler
    // get the length of the source string
    push    srcStr
    farc    std.strlen
    popr    srcLength,  1
    // find the offset of the separator character ':'
    push    srcStr
    push    separatorStr
    pshi    0
    farc    std.indexof
    popr    sepOffset,  3
    // allocate space for the first argument
    mov     arg1len,    sepOffset
    inc     arg1len
    new     arg1str,    arg1len
    // get the first argument
    push    arg1str
    push    srcStr
    pshi    0
    push    sepOffset
    farc    std.substr
    popn    4
    // increment the offset to skip over the seaprator cahracter
    inc     sepOffset
    // allocate space for the second argument
    mov     arg2len,    srcLength
    sub     arg2len,    sepOffset
    inc     arg2len
    new     arg2str,    arg2len
    // get the second argument
    push    arg2str
    push    srcStr
    push    sepOffset
    push    arg2len
    farc    std.substr
    popn    4

    jmp     .finished

.exceptionHandler:
    pshd    errorStr
    farc    std.cout
    popn    1

.missingSeparator:
    // return null if the separator couldnt be found or there was an error
    lrti    0

.finished:
    stor    arg1ptr,    arg1str
    stor    arg2ptr,    arg2str
    // return 1 to indicate success
    lrti    1

; -------------------------------------
printConnectingMsg:
    entf    2,  2
    // print out connection message
    pshd    connectingMsg0
    call    printStr
    push    0
    call    printStr
    pshd    connectingMsg1
    call    printStr
    push    1
    call    printStr
    pshd    connectingMsg2
    call    printStr
    pshd    newlineStr
    call    printStr
    popn    6

    lrtn

; -------------------------------------
printStr:
    entf    1,  1
    push    0
    farc    std.cout
    popn    1
    lrtn

; -------------------------------------
printInt:
    entf    1,  1
    push    0
    pshi    10
    farc    strlib.IntToStr
    farc    std.cout
    popn    3

    pshd    newlineStr
    call    printStr
    popn    1

    lrtn

; -------------------------------------
printInput:
    nvar    0,  buff
    entf    1,  1

    pshd    inputPrefix
    farc    std.cout
    popn    1

    push    buff
    farc    std.cout
    popn    1

    lrtn

; -------------------------------------
printOutput:
    nvar    0,  buff
    entf    1,  1

    pshd    outputPrefix
    farc    std.cout
    popn    1

    push    buff
    farc    std.cout
    popn    1

    lrtn

; -------------------------------------
stayAlive:
    retn

; -------------------------------------
partChannel:
    retn

; -------------------------------------
sendData:
    nvar    0,  connID
    nvar    1,  dataPtr
    nvar    2,  dataLen
    nvar    3,  sendResult

    nvar    4,  canSend

    entf    5,  3

    //pshd  sdStr0
    //call  printStr
    //push  dataPtr
    //call  printStr
    //pshd  sdStr1
    //call  printStr
    //push  dataLen
    //call  printInt
    //popn  4

    // can data be written to the connection?
    push    connID
    farc    net.canSend
    popr    canSend,    1

    // if zero, no data available
    jz      canSend,    .cantSend
    // if less than zero, error occurred
    jlz     canSend,    .errorEncountered

    push    dataPtr
    farc    std.strlen
    popr    dataLen,    1

    push    connID
    push    dataPtr
    push    dataLen
    farc    net.send
    popr    sendResult, 3
    //
    push    dataPtr
    call    printOutput
    popn    1
    // return the number of bytes sent
    lret    sendResult

.cantSend:
    lrti    0
.errorEncountered:
    lrti    -1

; -------------------------------------
; // returns the number of bytes read
; int recvData(uint connID, char* buff, uint size)
recvData:
    nvar    0,  connID
    nvar    1,  buff
    nvar    2,  size
    nvar    3,  canRecv
    nvar    4,  recvResult

    entf    5,  3
    // is data available to be read from the connection?
    push    connID
    farc    net.canRecv
    popr    canRecv,    1
    // if zero, no data available
    jz      canRecv,    .noData
    // if less than zero, error occurred
    jlz     canRecv,    .errorEncountered
    // fill the data buffer with null
    push    buff
    pshi    0
    push    size
    farc    std.memset
    popn    3
    // populate the data buffer with data from the socket
    push    connID
    push    buff
    push    size
    farc    net.recv
    popr    recvResult, 3
    // if nothing was read, exit
    jz      recvResult, .connectionClosed
    // if the result is < 0, the conn closed or there was an error
    jlz     recvResult, .errorEncountered

    lret    recvResult

.noData:
    lrti    0
.errorEncountered:
    lrti    -1
.connectionClosed:
    lrti    -2

; -------------------------------------
quit:
    retn

; -------------------------------------
memset:
    nvar    0,  buff
    nvar    1,  size
    //
    nvar    2,  offs
    nvar    3,  dptr
    nvar    4,  wval
    nvar    5,  diff
    //
    entf    6,  2
    //
    movi    offs,   0
    movi    wval,   0
    mov     dptr,   buff
    //
.loop:
    stor    dptr,   wval
    inc     dptr

    mov     diff,   dptr
    sub     diff,   buff

    jg      diff,   size,   .endLoop

    jmp     .loop

.endLoop:
    lrtn